ListView QML Type

The following example shows the definition of a simple list model defined in a file called ContactModel.qml:

import QtQuick 2.0

ListModel {
    ListElement {
        name: "Bill Smith"
        number: "555 3264"
    }
    ListElement {
        name: "John Brown"
        number: "555 8426"
    }
    ListElement {
        name: "Sam Wise"
        number: "555 0473"
    }
}

Another component can display this model data in a https://, like this:

import QtQuick 2.0

ListView {
    width: 180; height: 200

    model: ContactModel {}
    delegate: Text {
        text: name + ": " + number
    }
}

Here, the https:// creates a ContactModel component for its model, and a https:// item for its delegate. The view will create a new https:// component for each item in the model. Notice the delegate is able to access the model's name and number data directly.

An improved list view is shown below. The delegate is visually improved and is moved into a separate contactDelegate component.

Rectangle {
    width: 180; height: 200

    Component {
        id: contactDelegate
        Item {
            width: 180; height: 40
            Column {
                Text { text: '<b>Name:</b> ' + name }
                Text { text: '<b>Number:</b> ' + number }
            }
        }
    }

    ListView {
        anchors.fill: parent
        model: ContactModel {}
        delegate: contactDelegate
        highlight: Rectangle { color: "lightsteelblue"; radius: 5 }
        focus: true
    }
}

The currently selected item is highlighted with a blue https:// using the https:// property, and focus is set to true to enable keyboard navigation for the list view. The list view itself is a focus scope (see https:// for more details).

Delegates are instantiated as needed and may be destroyed at any time. They are parented to https://'s https://, not to the view itself. State should never be stored in a delegate.

https:// attaches a number of properties to the root item of the delegate, for example ListView.isCurrentItem. In the following example, the root delegate item can access this attached property directly as ListView.isCurrentItem, while the child contactInfo object must refer to this property as wrapper.ListView.isCurrentItem.

ListView {
    width: 180; height: 200

    Component {
        id: contactsDelegate
        Rectangle {
            id: wrapper
            width: 180
            height: contactInfo.height
            color: ListView.isCurrentItem ? "black" : "red"
            Text {
                id: contactInfo
                text: name + ": " + number
                color: wrapper.ListView.isCurrentItem ? "red" : "black"
            }
        }
    }

    model: ContactModel {}
    delegate: contactsDelegate
    focus: true
}

The layout of the items in a https:// can be controlled by these properties:

• https:// - controls whether items flow horizontally or vertically. This value can be either Qt.Horizontal or Qt.Vertical.

• https:// - controls the horizontal layout direction for a horizontally-oriented view: that is, whether items are laid out from the left side of the view to the right, or vice-versa. This value can be either Qt.LeftToRight or Qt.RightToLeft.

• https:// - controls the vertical layout direction for a vertically-oriented view: that is, whether items are laid out from the top of the view down towards the bottom of the view, or vice-versa. This value can be either https://.TopToBottom or https://.BottomToTop.

By default, a https:// has a vertical orientation, and items are laid out from top to bottom. The table below shows the different layouts that a https:// can have, depending on the values of the properties listed above.

ListViews with Qt.Vertical orientation
Top to bottom	Bottom to top

ListViews with Qt.Horizontal orientation
Left to right	Right to left

By default, a vertical https:// sets https:// to Flickable.Vertical, and a horizontal https:// sets it to Flickable.Horizontal. Furthermore, a vertical https:// only calculates (estimates) the https://, and a horizontal https:// only calculates the https://. The other dimension is set to -1.

Since Qt 5.9 (Qt Quick 2.9), it is possible to make a https:// that can be flicked to both directions. In order to do this, the https:// can be set to Flickable.AutoFlickDirection or Flickable.AutoFlickIfNeeded, and the desired contentWidth or contentHeight must be provided.

ListView {
    width: 180; height: 200

    contentWidth: 320
    flickableDirection: Flickable.AutoFlickDirection

    model: ContactModel {}
    delegate: Row {
        Text { text: '<b>Name:</b> ' + name; width: 160 }
        Text { text: '<b>Number:</b> ' + number; width: 160 }
    }
}

The Z value of items determines whether they are rendered above or below other items. https:// uses several different default Z values, depending on what type of item is being created:

These default values are set if the Z value of the item is 0, so setting the Z value of these items to 0 has no effect. Note that the Z value is of type https://, so it is possible to set fractional values like 0.1.

See also https://, https://, https://, https://

currentItem : Item

The currentIndex property holds the index of the current item, and currentItem holds the current item. Setting the https:// to -1 will clear the highlight and set https:// to null.

If https:// is true, setting either of these properties will smoothly scroll the https:// so that the current item becomes visible.

Note that the position of the current item may only be approximate until it becomes visible in the view.

preferredHighlightBegin : real

preferredHighlightEnd : real

These properties define the preferred range of the highlight (for the current item) within the view. The preferredHighlightBegin value must be less than the preferredHighlightEnd value.

These properties affect the position of the current item when the list is scrolled. For example, if the currently selected item should stay in the middle of the list when the view is scrolled, set the preferredHighlightBegin and preferredHighlightEnd values to the top and bottom coordinates of where the middle item would be. If the currentItem is changed programmatically, the list will automatically scroll so that the current item is in the middle of the view. Furthermore, the behavior of the current item index will occur whether or not a highlight exists.

Valid values for highlightRangeMode are:

• https://.ApplyRange - the view attempts to maintain the highlight within the range. However, the highlight can move outside of the range at the ends of the list or due to mouse interaction.

• https://.StrictlyEnforceRange - the highlight never moves outside of the range. The current item changes if a keyboard or mouse action would cause the highlight to move outside of the range.

• https://.NoHighlightRange - this is the default value.

[since QtQuick 2.3] displayMarginEnd : int

This property allows delegates to be displayed outside of the view geometry.

If this value is non-zero, the view will create extra delegates before the start of the view, or after the end. The view will create as many delegates as it can fit into the pixel size specified.

For example, if in a vertical view the delegate is 20 pixels high and displayMarginBeginning and displayMarginEnd are both set to 40, then 2 delegates above and 2 delegates below will be created and shown.

The default value is 0.

This property is meant for allowing certain UI configurations, and not as a performance optimization. If you wish to create delegates outside of the view geometry for performance reasons, you probably want to use the https:// property instead.

This QML property was introduced in QtQuick 2.3.

highlightMoveVelocity : real

highlightResizeDuration : int

highlightResizeVelocity : real

These properties control the speed of the move and resize animations for the highlight delegate.

https:// must be true for these properties to have effect.

The default value for the velocity properties is 400 pixels/second. The default value for the duration properties is -1, i.e. the highlight will take as much time as necessary to move at the set speed.

These properties have the same characteristics as a https://: if both the velocity and duration are set, the animation will use whichever gives the shorter duration.

The move velocity and duration properties are used to control movement due to index changes; for example, when https://() is called. When the user flicks a https://, the velocity from the flick is used to control the movement instead.

To set only one property, the other can be set to -1. For example, if you only want to animate the duration and not velocity, use the following code:

highlightMoveDuration: 1000
highlightMoveVelocity: -1

See Also▲

This property holds the transition to apply to items that are added to the view.

For example, here is a view that specifies such a transition:

ListView {
    ...
    add: Transition {
        NumberAnimation { properties: "x,y"; from: 100; duration: 1000 }
    }
}

Whenever an item is added to the above view, the item will be animated from the position (100,100) to its final x,y position within the view, over one second. The transition only applies to the new items that are added to the view; it does not apply to the items below that are displaced by the addition of the new items. To animate the displaced items, set the https:// or https:// properties.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the transition to apply to items within the view that are displaced by the addition of other items to the view.

For example, here is a view that specifies such a transition:

ListView {
    ...
    addDisplaced: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

Whenever an item is added to the above view, all items beneath the new item are displaced, causing them to move down (or sideways, if horizontally orientated) within the view. As this displacement occurs, the items' movement to their new x,y positions within the view will be animated by a https:// over one second, as specified. This transition is not applied to the new item that has been added to the view; to animate the added items, set the https:// property.

If an item is displaced by multiple types of operations at the same time, it is not defined as to whether the addDisplaced, https:// or https:// transition will be applied. Additionally, if it is not necessary to specify different transitions depending on whether an item is displaced by an add, move or remove operation, consider setting the https:// property instead.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property determines whether delegates are retained outside the visible area of the view.

If this value is greater than zero, the view may keep as many delegates instantiated as it can fit within the buffer specified. For example, if in a vertical view the delegate is 20 pixels high and cacheBuffer is set to 40, then up to 2 delegates above and 2 delegates below the visible area may be created/retained. The buffered delegates are created asynchronously, allowing creation to occur across multiple frames and reducing the likelihood of skipping frames. In order to improve painting performance delegates outside the visible area are not painted.

The default value of this property is platform dependent, but will usually be a value greater than zero. Negative values are ignored.

Note that cacheBuffer is not a pixel buffer - it only maintains additional instantiated delegates.

The cacheBuffer operates outside of any display margins specified by https:// or https://.

This property holds the number of items in the view.

This property holds the section that is currently at the beginning of the view.

The delegate provides a template defining each item instantiated by the view. The index is exposed as an accessible index property. Properties of the model are also available depending upon the type of https://.

The number of objects and bindings in the delegate has a direct effect on the flicking performance of the view. If at all possible, place functionality that is not needed for the normal display of the delegate in a https:// which can load additional components when needed.

The https:// will lay out the items based on the size of the root item in the delegate.

It is recommended that the delegate's size be a whole number to avoid sub-pixel alignment of items.

The default stacking order of delegate instances is 1.

See Also▲

This property holds the generic transition to apply to items that have been displaced by any model operation that affects the view.

This is a convenience for specifying the generic transition to be applied to any items that are displaced by an add, move or remove operation, without having to specify the individual https://, https:// and https:// properties. For example, here is a view that specifies a displaced transition:

ListView {
    ...
    displaced: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

When any item is added, moved or removed within the above view, the items below it are displaced, causing them to move down (or sideways, if horizontally orientated) within the view. As this displacement occurs, the items' movement to their new x,y positions within the view will be animated by a https:// over one second, as specified.

If a view specifies this generic displaced transition as well as a specific https://, https:// or https:// transition, the more specific transition will be used instead of the generic displaced transition when the relevant operation occurs, providing that the more specific transition has not been disabled (by setting https:// to false). If it has indeed been disabled, the generic displaced transition is applied instead.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the effective layout direction of a horizontally-oriented list.

When using the attached property https:// for locale layouts, the visual layout direction of the horizontal list will be mirrored. However, the property https:// will remain unchanged.

See Also▲

This property holds the component to use as the footer.

An instance of the footer component is created for each view. The footer is positioned at the end of the view, after any items. The default stacking order of the footer is 1.

See Also▲

This holds the footer item created from the https:// component.

An instance of the footer component is created for each view. The footer is positioned at the end of the view, after any items. The default stacking order of the footer is 1.

See Also▲

This property determines the positioning of the https://.

The possible values are:

• https://.InlineFooter (default) - the footer is positioned in the end of the content and moves together with the content like an ordinary item.

• https://.OverlayFooter - the footer is positioned in the end of the view.

• https://.PullBackFooter - the footer is positioned in the end of the view. The footer can be pushed away by moving the content backwards, and pulled back by moving the content forwards.

This property was introduced in Qt 5.4.

This property holds the component to use as the header.

An instance of the header component is created for each view. The header is positioned at the beginning of the view, before any items. The default stacking order of the header is 1.

See Also▲

This holds the header item created from the https:// component.

An instance of the header component is created for each view. The header is positioned at the beginning of the view, before any items. The default stacking order of the header is 1.

See Also▲

This property determines the positioning of the https://.

The possible values are:

• https://.InlineHeader (default) - the header is positioned in the beginning of the content and moves together with the content like an ordinary item.

• https://.OverlayHeader - the header is positioned in the beginning of the view.

• https://.PullBackHeader - the header is positioned in the beginning of the view. The header can be pushed away by moving the content forwards, and pulled back by moving the content backwards.

This property was introduced in Qt 5.4.

This property holds the component to use as the highlight.

An instance of the highlight component is created for each list. The geometry of the resulting component instance is managed by the list so as to stay with the current item, unless the https:// property is false. The default stacking order of the highlight item is 0.

See Also▲

This property holds whether the highlight is managed by the view.

If this property is true (the default value), the highlight is moved smoothly to follow the current item. Otherwise, the highlight is not moved by the view, and any movement must be implemented by the highlight.

Here is a highlight with its motion defined by a https:// item:

Component {
    id: highlight
    Rectangle {
        width: 180; height: 40
        color: "lightsteelblue"; radius: 5
        y: list.currentItem.y
        Behavior on y {
            SpringAnimation {
                spring: 3
                damping: 0.2
            }
        }
    }
}

ListView {
    id: list
    width: 180; height: 200
    model: ContactModel {}
    delegate: Text { text: name }

    highlight: highlight
    highlightFollowsCurrentItem: false
    focus: true
}

Note that the highlight animation also affects the way that the view is scrolled. This is because the view moves to maintain the highlight within the preferred highlight range (or visible viewport).

See Also▲

This holds the highlight item created from the https:// component.

The highlightItem is managed by the view unless https:// is set to false. The default stacking order of the highlight item is 0.

See Also▲

This property holds whether the key navigation of the list is enabled.

If this is true, the user can navigate the view with a keyboard. It is useful for applications that need to selectively enable or disable mouse and keyboard interaction.

By default, the value of this property is bound to https:// to ensure behavior compatibility for existing applications. When explicitly set, it will cease to be bound to the interactive property.

This property was introduced in Qt 5.7.

See Also▲

This property holds whether the list wraps key navigation.

If this is true, key navigation that would move the current item selection past the end of the list instead wraps around and moves the selection to the start of the list, and vice-versa.

By default, key navigation is not wrapped.

This property holds the layout direction of a horizontally-oriented list.

Possible values:

• Qt.LeftToRight (default) - Items will be laid out from left to right.

• Qt.RightToLeft - Items will be laid out from right to let.

Setting this property has no effect if the https:// is Qt.Vertical.

See Also▲

This property holds the model providing data for the list.

The model provides the set of data that is used to create the items in the view. Models can be created directly in QML using https://, https:// or https://, or provided by C++ model classes. If a C++ model class is used, it must be a subclass of QAbstractItemModel or a simple list.

See Also▲

This property holds the transition to apply to items in the view that are being moved due to a move operation in the view's https://.

For example, here is a view that specifies such a transition:

ListView {
    ...
    move: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

Whenever the https:// performs a move operation to move a particular set of indexes, the respective items in the view will be animated to their new positions in the view over one second. The transition only applies to the items that are the subject of the move operation in the model; it does not apply to items below them that are displaced by the move operation. To animate the displaced items, set the https:// or https:// properties.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the transition to apply to items that are displaced by a move operation in the view's https://.

For example, here is a view that specifies such a transition:

ListView {
    ...
    moveDisplaced: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

Whenever the https:// performs a move operation to move a particular set of indexes, the items between the source and destination indexes of the move operation are displaced, causing them to move upwards or downwards (or sideways, if horizontally orientated) within the view. As this displacement occurs, the items' movement to their new x,y positions within the view will be animated by a https:// over one second, as specified. This transition is not applied to the items that are the actual subjects of the move operation; to animate the moved items, set the https:// property.

If an item is displaced by multiple types of operations at the same time, it is not defined as to whether the https://, moveDisplaced or https:// transition will be applied. Additionally, if it is not necessary to specify different transitions depending on whether an item is displaced by an add, move or remove operation, consider setting the https:// property instead.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the orientation of the list.

Possible values:

• https://.Horizontal - Items are laid out horizontally

• https://.Vertical (default) - Items are laid out vertically

Horizontal orientation:

Vertical orientation:

See Also▲

This property holds the transition to apply to the items that are initially created for a view.

It is applied to all items that are created when:

• The view is first created

• The view's https:// changes in such a way that the visible delegates are completely replaced

• The view's https:// is reset, if the model is a QAbstractItemModel subclass

For example, here is a view that specifies such a transition:

ListView {
    ...
    populate: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

When the view is initialized, the view will create all the necessary items for the view, then animate them to their correct positions within the view over one second.

However when scrolling the view later, the populate transition does not run, even though delegates are being instantiated as they become visible. When the model changes in a way that new delegates become visible, the https:// transition is the one that runs. So you should not depend on the populate transition to initialize properties in the delegate, because it does not apply to every delegate. If your animation sets the to value of a property, the property should initially have the to value, and the animation should set the from value in case it is animated:

ListView {
    ...
    delegate: Rectangle {
        opacity: 1 // not necessary because it's the default
    }
    populate: Transition {
        NumberAnimation { property: "opacity"; from: 0; to: 1; duration: 1000 }
    }
}

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the transition to apply to items that are removed from the view.

For example, here is a view that specifies such a transition:

ListView {
    ...
    remove: Transition {
        ParallelAnimation {
            NumberAnimation { property: "opacity"; to: 0; duration: 1000 }
            NumberAnimation { properties: "x,y"; to: 100; duration: 1000 }
        }
    }
}

Whenever an item is removed from the above view, the item will be animated to the position (100,100) over one second, and in parallel will also change its opacity to 0. The transition only applies to the items that are removed from the view; it does not apply to the items below them that are displaced by the removal of the items. To animate the displaced items, set the https:// or https:// properties.

Note that by the time the transition is applied, the item has already been removed from the model; any references to the model data for the removed index will not be valid.

Additionally, if the https:// attached property has been set for a delegate item, the remove transition will not be applied until https:// becomes false again.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

This property holds the transition to apply to items in the view that are displaced by the removal of other items in the view.

For example, here is a view that specifies such a transition:

ListView {
    ...
    removeDisplaced: Transition {
        NumberAnimation { properties: "x,y"; duration: 1000 }
    }
}

Whenever an item is removed from the above view, all items beneath it are displaced, causing them to move upwards (or sideways, if horizontally orientated) within the view. As this displacement occurs, the items' movement to their new x,y positions within the view will be animated by a https:// over one second, as specified. This transition is not applied to the item that has actually been removed from the view; to animate the removed items, set the https:// property.

If an item is displaced by multiple types of operations at the same time, it is not defined as to whether the https://, https:// or removeDisplaced transition will be applied. Additionally, if it is not necessary to specify different transitions depending on whether an item is displaced by an add, move or remove operation, consider setting the https:// property instead.

For more details and examples on how to use view transitions, see the https:// documentation.

See Also▲

section.criteria : enumeration

section.delegate : Component

section.labelPositioning : enumeration

section.property : string

These properties determine the expression to be evaluated and appearance of the section labels.

section.property holds the name of the property that is the basis of each section.

section.criteria holds the criteria for forming each section based on section.property. This value can be one of:

• ViewSection.FullString (default) - sections are created based on the section.property value.

• ViewSection.FirstCharacter - sections are created based on the first character of the section.property value (for example, 'A', 'B', 'C' sections, etc. for an address book)

A case insensitive comparison is used when determining section boundaries.

section.delegate holds the delegate component for each section. The default stacking order of section delegate instances is 2.

section.labelPositioning determines whether the current and/or next section labels stick to the start/end of the view, and whether the labels are shown inline. This value can be a combination of:

• ViewSection.InlineLabels - section labels are shown inline between the item delegates separating sections (default).

• ViewSection.CurrentLabelAtStart - the current section label sticks to the start of the view as it is moved.

• ViewSection.NextLabelAtEnd - the next section label (beyond all visible sections) sticks to the end of the view as it is moved.

  Enabling ViewSection.NextLabelAtEnd requires the view to scan ahead for the next section, which has performance implications, especially for slower models.

Each item in the list has attached properties named ListView.section, ListView.previousSection and ListView.nextSection.

For example, here is a https:// that displays a list of animals, separated into sections. Each item in the https:// is placed in a different section depending on the "size" property of the model item. The sectionHeading delegate component provides the light blue bar that marks the beginning of each section.

    // The delegate for each section header
    Component {
        id: sectionHeading
        Rectangle {
            width: container.width
            height: childrenRect.height
            color: "lightsteelblue"

            Text {
                text: section
                font.bold: true
                font.pixelSize: 20
            }
        }
    }

    ListView {
        id: view
        anchors.top: parent.top
        anchors.bottom: buttonBar.top
        width: parent.width
        model: animalsModel
        delegate: Text { text: name; font.pixelSize: 18 }

        section.property: "size"
        section.criteria: ViewSection.FullString
        section.delegate: sectionHeading
    }

See Also▲

This property determines how the view scrolling will settle following a drag or flick. The possible values are:

• https://.NoSnap (default) - the view stops anywhere within the visible area.

• https://.SnapToItem - the view settles with an item aligned with the start of the view.

• https://.SnapOneItem - the view settles no more than one item away from the first visible item at the time the mouse button is released. This mode is particularly useful for moving one page at a time. When SnapOneItem is enabled, the https:// will show a stronger affinity to neighboring items when movement occurs. For example, a short drag that snaps back to the current item with SnapToItem might snap to a neighboring item with SnapOneItem.

snapMode does not affect the https://. To update the https:// as the list is moved, set https:// to ListView.StrictlyEnforceRange.

See Also▲

This property holds the spacing between items.

The default value is 0.

This property holds the layout direction of a vertically-oriented list.

Possible values:

• https://.TopToBottom (default) - Items are laid out from the top of the view down to the bottom of the view.

• https://.BottomToTop - Items are laid out from the bottom of the view up to the top of the view.

Setting this property has no effect if the https:// is Qt.Horizontal.

See Also▲

This attached property holds whether the delegate may be destroyed. It is attached to each instance of the delegate. The default value is false.

It is sometimes necessary to delay the destruction of an item until an animation completes. The example delegate below ensures that the animation completes before the item is removed from the list.

Component {
    id: delegate
    Item {
        ListView.onRemove: SequentialAnimation {
            PropertyAction { target: wrapper; property: "ListView.delayRemove"; value: true }
            NumberAnimation { target: wrapper; property: "scale"; to: 0; duration: 250; easing.type: Easing.InOutQuad }
            PropertyAction { target: wrapper; property: "ListView.delayRemove"; value: false }
        }
    }
}

If a https:// transition has been specified, it will not be applied until delayRemove is returned to false.

This attached property is true if this delegate is the current item; otherwise false.

It is attached to each instance of the delegate.

This property may be used to adjust the appearance of the current item, for example:

ListView {
    width: 180; height: 200

    Component {
        id: contactsDelegate
        Rectangle {
            id: wrapper
            width: 180
            height: contactInfo.height
            color: ListView.isCurrentItem ? "black" : "red"
            Text {
                id: contactInfo
                text: name + ": " + number
                color: wrapper.ListView.isCurrentItem ? "red" : "black"
            }
        }
    }

    model: ContactModel {}
    delegate: contactsDelegate
    focus: true
}

This attached property holds the section of the next element.

It is attached to each instance of the delegate.

The section is evaluated using the https:// properties.

This attached property holds the section of the previous element.

It is attached to each instance of the delegate.

The section is evaluated using the https:// properties.

This attached property holds the section of this element.

It is attached to each instance of the delegate.

The section is evaluated using the https:// properties.

This attached property holds the view that manages this delegate instance.

It is attached to each instance of the delegate and also to the header, the footer, the section and the highlight delegates.

This attached signal is emitted immediately after an item is added to the view.

If an add transition is specified, it is applied immediately after this signal is handled.

The corresponding handler is onAdd.

This attached signal is emitted immediately before an item is removed from the view.

If a remove transition has been specified, it is applied after this signal is handled, providing that https:// is false.

The corresponding handler is onRemove.

positionViewAtEnd()

Positions the view at the beginning or end, taking into account any header or footer.

It is not recommended to use https:// or https:// to position the view at a particular index. This is unreliable since removing items from the start of the list does not cause all other items to be repositioned, and because the actual start of the view can vary based on the size of the delegates.

Note: methods should only be called after the Component has completed. To position the view at startup, this method should be called by Component.onCompleted. For example, to position the view at the end on startup:

Component.onCompleted: positionViewAtEnd()

Decrements the current index. The current index will wrap if https:// is true and it is currently at the beginning. This method has no effect if the https:// is zero.

Note: methods should only be called after the Component has completed.

Responding to changes in the model is usually batched to happen only once per frame. This means that inside script blocks it is possible for the underlying model to have changed, but the https:// has not caught up yet.

This method forces the https:// to immediately respond to any outstanding changes in the model.

Note: methods should only be called after the Component has completed.

This method was introduced in Qt 5.1.

Increments the current index. The current index will wrap if https:// is true and it is currently at the end. This method has no effect if the https:// is zero.

Note: methods should only be called after the Component has completed.

Returns the index of the visible item containing the point x, y in content coordinates. If there is no item at the point specified, or the item is not visible -1 is returned.

If the item is outside the visible area, -1 is returned, regardless of whether an item will exist at that point when scrolled into view.

Note: methods should only be called after the Component has completed.

Returns the visible item containing the point x, y in content coordinates. If there is no item at the point specified, or the item is not visible null is returned.

If the item is outside the visible area, null is returned, regardless of whether an item will exist at that point when scrolled into view.

Note: methods should only be called after the Component has completed.

Returns the item for index. If there is no item for that index, for example because it has not been created yet, or because it has been panned out of the visible area and removed from the cache, null is returned.

Note: this method should only be called after the Component has completed. The returned value should also not be stored since it can turn to null as soon as control goes out of the calling scope, if the view releases that item.

This method was introduced in Qt 5.13.

Positions the view such that the index is at the position specified by mode:

• https://.Beginning - position item at the top (or left for horizontal orientation) of the view.

• https://.Center - position item in the center of the view.

• https://.End - position item at bottom (or right for horizontal orientation) of the view.

• https://.Visible - if any part of the item is visible then take no action, otherwise bring the item into view.

• https://.Contain - ensure the entire item is visible. If the item is larger than the view the item is positioned at the top (or left for horizontal orientation) of the view.

• https://.SnapPosition - position the item at https://. This mode is only valid if https:// is StrictlyEnforceRange or snapping is enabled via https://.

If positioning the view at index would cause empty space to be displayed at the beginning or end of the view, the view will be positioned at the boundary.

It is not recommended to use https:// or https:// to position the view at a particular index. This is unreliable since removing items from the start of the list does not cause all other items to be repositioned, and because the actual start of the view can vary based on the size of the delegates. The correct way to bring an item into view is with positionViewAtIndex.

Note: methods should only be called after the Component has completed. To position the view at startup, this method should be called by Component.onCompleted. For example, to position the view at the end:

Component.onCompleted: positionViewAtIndex(count - 1, ListView.Beginning)