Palette QML Type

A palette consists of three color groups: active, disabled, and inactive. The active color group is the default group: its colors are used for other groups if colors of these groups aren't explicitly specified.

In the following example, color is applied for all color groups:

ApplicationWindow {
    palette.buttonText: "salmon"

    ColumnLayout {
        Button {
            text: qsTr("Disabled button")
            enabled: false
        }

        Button {
            text: qsTr("Enabled button")
        }
    }
}

It means that text color will be the same for both buttons.

In the following example, colors will be different for enabled and disabled states:

ApplicationWindow {
    palette.buttonText: "salmon"
    palette.disabled.buttonText: "lavender"

    ColumnLayout {
        Button {
            text: qsTr("Disabled button")
            enabled: false
        }

        Button {
            text: qsTr("Enabled button")
        }
    }
}

It is also possible to specify colors like this:

palette {
    buttonText: "red"
    button: "khaki"

    disabled {
        buttonText: "lavender"
        button: "coral"
    }
}

This approach is especially convenient when you need to specify a whole palette with all color groups; but as with the other cases above, the colors that are not specified are initialized from SystemPalette, or potentially the Qt Quick Controls style, if one is in use.

See Also▲

active : ColorGroup▲

disabled : ColorGroup▲

inactive : ColorGroup▲