reportGlobals.xq Example File
xmlpatterns/xquery/globalVariables/reportGlobals.xq

 (:
     This XQuery loads a GCC-XML file and reports the locations of all
     global variables in the original C++ source. To run the query,
     use the command line:

     xmlpatterns reportGlobals.xq -param fileToOpen=globals.gccxml -output globals.html

     "fileToOpen=globals.gccxml" binds the file name "globals.gccxml"
     to the variable "fileToOpen" declared and used below.
 :)

 declare variable $fileToOpen as xs:anyURI external;
 declare variable $inDoc as document-node() := doc($fileToOpen);

 (:
    This function determines whether the typeId is a complex type,
    e.g. QString. We only check whether it's a class. To be strictly
    correct, we should check whether the class has a non-synthesized
    constructor. We accept both mutable and const types.
 :)
 declare function local:isComplexType($typeID as xs:string) as xs:boolean
 {
     exists($inDoc/GCC_XML/Class[@id = $typeID])
     or
     exists($inDoc/GCC_XML/Class[@id = $inDoc/GCC_XML/CvQualifiedType[@id = $typeID]/@type])
 };

 (:
    This function determines whether the typeId is a primitive type.
 :)
 declare function local:isPrimitive($typeId as xs:string) as xs:boolean
 {
     exists($inDoc/GCC_XML/FundamentalType[@id = $typeId])
 };

 (:
    This function constructs a line for the report. The line contains
    a variable name, the source file, and the line number.
 :)
 declare function local:location($block as element()) as xs:string
 {
     concat($inDoc/GCC_XML/File[@id = $block/@file]/@name, " at line ", $block/@line)
 };

 (:
    This function generates the report. Note that it is called once
    in the <body> element of the <html> output.

    It ignores const variables of simple types but reports all others.
 :)
 declare function local:report() as element()+
 {
     let $complexVariables as element(Variable)* := $inDoc/GCC_XML/Variable[local:isComplexType(@type)]
     return if (exists($complexVariables))
            then (<p xmlns="http://www.w3.org/1999/xhtml/">Global variables with complex types:</p>,
                  <ol xmlns="http://www.w3.org/1999/xhtml/">
                     {
                         (: For each Variable in $complexVariables... :)
                         $complexVariables/<li><span class="variableName">{string(@name)}</span> in {local:location(.)}</li>
                     }
                  </ol>)
            else <p xmlns="http://www.w3.org/1999/xhtml/">No complex global variables found.</p>

     ,

     let $primitiveVariables as element(Variable)+ := $inDoc/GCC_XML/Variable[local:isPrimitive(@type)]
     return if (exists($primitiveVariables))
            then (<p xmlns="http://www.w3.org/1999/xhtml/">Mutable global variables with primitives types:</p>,
                  <ol xmlns="http://www.w3.org/1999/xhtml/">
                     {
                         (: For each Variable in $complexVariables... :)
                         $primitiveVariables/<li><span class="variableName">{string(@name)}</span> in {local:location(.)}</li>
                     }
                  </ol>)
            else <p xmlns="http://www.w3.org/1999/xhtml/">No mutable primitive global variables found.</p>
 };

 (:
     This is where the <html> report is output. First
     there is some style stuff, then the <body> element,
     which contains the call to the \c{local:report()}
     declared above.
 :)
 <html xmlns="http://www.w3.org/1999/xhtml/" xml:lang="en" lang="en">
     <head>
         <title>Global variables report for {$fileToOpen}</title>
     </head>
     <style type="text/css">
         .details
         {{
             text-align: left;
             font-size: 80%;
             color: blue
         }}
         .variableName
         {{
             font-family: courier;
             color: blue
         }}
     </style>

     <body>
         <p class="details">Start report: {current-dateTime()}</p>
         {
             local:report()
         }
         <p class="details">End report: {current-dateTime()}</p>
     </body>

 </html>

Best Of

Actualités les plus lues

Semaine

Mois

Année

Le Qt Developer Network au hasard

Comment fermer une application

Le Qt Developer Network est un réseau de développeurs Qt anglophone, où ils peuvent partager leur expérience sur le framework. Lire l'article.

Communauté

Ressources

Liens utiles

Contact

Vous souhaitez rejoindre la rédaction ou proposer un tutoriel, une traduction, une question... ? Postez dans le forum Contribuez ou contactez-nous par MP ou par email (voir en bas de page).

Qt dans le magazine

Cette page est une traduction d'une page de la documentation de Qt, écrite par Nokia Corporation and/or its subsidiary(-ies). Les éventuels problèmes résultant d'une mauvaise traduction ne sont pas imputables à Nokia.	Qt 4.6-snapshot
Copyright © 2012 Developpez LLC. Tous droits réservés Developpez LLC. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents et images sans l'autorisation expresse de Developpez LLC. Sinon, vous encourez selon la loi jusqu'à 3 ans de prison et jusqu'à 300 000 E de dommages et intérêts. Cette page est déposée à la SACD.
Vous avez déniché une erreur ? Un bug ? Une redirection cassée ? Ou tout autre problème, quel qu'il soit ? Ou bien vous désirez participer à ce projet de traduction ? N'hésitez pas à nous contacter ou par MP !