Modules

Writing a qmltypes file

QML modules may refer to one or more type information files in their qmldir file. These usually have the .qmltypes extension and are read by external tools to gain information about types defined in plugins.

As such qmltypes files have no effect on the functionality of a QML module. Their only use is to allow tools such as Qt Creator to provide code completion, error checking and other functionality to users of your module.

Any module that uses plugins should also ship a type description file.

The best way to create a qmltypes file for your module is to generate it using the qmlplugindump tool that is provided with Qt.

Example: If your module is in /tmp/imports/My/Module, you could run

 qmlplugindump My.Module 1.0 /tmp/imports > /tmp/imports/My/Module/mymodule.qmltypes

to generate type information for your module. Afterwards, add the line

 typeinfo mymodule.qmltypes

to /tmp/imports/My/Module/qmldir to register it.

While the qmldump tool covers most cases, it does not work if:

• The plugin uses a QDeclarativeCustomParser. The component that uses the custom parser will not get its members documented.
• The plugin can not be loaded. In particular if you cross-compiled the plugin for a different architecture, qmldump will not be able to load it.

In case you have to create a qmltypes file manually or need to adjust an existing one, this is the file format:

 import QtQuick.tooling 1.1

 // There always is a single Module object that contains all
 // Component objects.
 Module {
     // A Component object directly corresponds to a type exported
     // in a plugin with a call to qmlRegisterType.
     Component {

         // The name is a unique identifier used to refer to this type.
         // It is recommended you simply use the C++ type name.
         name: "QDeclarativeAbstractAnimation"

         // The name of the prototype Component.
         prototype: "QObject"

         // The name of the default property.
         defaultProperty: "animations"

         // The name of the type containing attached properties
         // and methods.
         attachedType: "QDeclarativeAnimationAttached"

         // The list of exports determines how a type can be imported.
         // Each string has the format "URI/Name version" and matches the
         // arguments to qmlRegisterType. Usually types are only exported
         // once, if at all.
         // If the "URI/" part of the string is missing that means the
         // type should be put into the package defined by the URI the
         // module was imported with.
         // For example if this module was imported with 'import Foo 4.8'
         // the Animation object would be found in the package Foo and
         // QtQuick.
         exports: [
             "Animation 4.7",
             "QtQuick/Animation 1.0"
         ]

         Property {
             name: "animations";
             type: "QDeclarativeAbstractAnimation"
             // defaults to false, whether this property is read only
             isReadonly: true
             // defaults to false, whether the type of this property was a pointer in C++
             isPointer: true
             // defaults to false: whether the type actually is a QDeclarativeListProperty<type>
             isList: true
             // defaults to 0: the minor version that introduced this property
             revision: 1
         }
         Property { name: "loops"; type: "int" }
         Property { name: "name"; type: "string" }
         Property { name: "loopsEnum"; type: "Loops" }

         Enum {
             name: "Loops"
             values: {
                 "Infinite": -2,
                 "OnceOnly": 1
             }
         }

         // Signal and Method work the same way. The inner Parameter
         // declarations also support the isReadonly, isPointer and isList
         // attributes which mean the same as for Property
         Method { name: "restart" }
         Signal { name: "started"; revision: 2 }
         Signal {
             name: "runningChanged"
             Parameter { type: "bool" }
             Parameter { name: "foo"; type: "bool" }
         }
     }
 }