Connectivity QML Plugin

Using the NFC API

Near Field Communication(NFC) has a range of only about a centimeter. It can therefore be used as a contact based method of validation or discovery for other communications channels, often in the form "Touch to Play".

The NFC part of the Connectivity API provides QML elements to communicate peer-to-peer using LLCP sockets ( NearFieldSocket ), NDEF records of various types that encapsulate messages, a filtering mechanism on messages and The NearField element that starts the process.

Declaring a NearField element results in the creation of supporting objects include platform specific features. In the QML Poster Example, a NearField element is declared with id nearfield. This includes a filter constructed from two NdefFilters. The filters have the type specified by a string such as "urn:nfc:wkt:U", which identifies the type as being an NFC Well Known Type, that is predefined, of "U" representing a URL. The other NdefFilter element is for a Well Known Type of "T" (Text).

         filter: [
             NdefFilter { type: "urn:nfc:wkt:U"; minimum: 1; maximum: 1 },
             NdefFilter { type: "urn:nfc:wkt:T"; minimum: 1 }
         ]

The NearField element has the properties of filter, messageRecords and orderMatch. The filter is a list of NdefFilter elements. The orderMatch property is a boolean that indicates if the order of the records in the filter is important, in the example this property is not used. The messageRecords property is a list of NdefRecords containing the results of the last read. When the signal messageRecordsChanged() is emitted the slot onMessageRecordsChanged can iterate through the messageRecords list selecting particular types. In the example, after all records in the messageRecords list have been examined the state of the example is set to "Show" which displays the results.

         onMessageRecordsChanged: {
             posterText.text = "";
             posterImage.source = "";
             posterUrl.text = "";

             var currentLocaleMatch = NdefTextRecord.LocaleMatchedNone;
             var i;
             for (i = 0; i < messageRecords.length; ++i) {
                 if (messageRecords[i].recordType == "urn:nfc:wkt:T") {
                     if (messageRecords[i].localeMatch > currentLocaleMatch) {
                         currentLocaleMatch = messageRecords[i].localeMatch;
                         posterText.text = messageRecords[i].text;
                     }
                 } else if (messageRecords[i].recordType == "urn:nfc:wkt:U") {
                     posterUrl.text = messageRecords[i].uri;
                 } else if (messageRecords[i].recordType.substr(0, 19) == "urn:nfc:mime:image/") {
                     posterImage.source = messageRecords[i].uri;
                 }
             }

             root.state = "show";
         }

We have not covered the NearFieldSocket element. This is not used in the poster example, however in the QML Tennis Demo we see the use of the element in the handover code from NFC to Bluetooth. The code here shows the socket element and the slot onDataAvailable which parses the text payload of the application message. The uri identifies the service that the client is connecting to or the service that the server is registering.

     NearFieldSocket {
         id: socket

         uri: "urn:nfc:sn:com.nokia.qtmobility.tennis"
         connected: true

         function parse(s) {
             var args = s.split(" ");
             if (args.length == 2) {
                 bluetoothService.deviceAddress = args[0];
                 bluetoothService.servicePort = args[1];
                 root.bluetoothServiceChanged();
             }
         }

         onDataAvailable: parse(socket.stringData)

         onStateChanged: {
             if (state == "Connecting") {
                 available = true;
             }
         }
     }