qmake Tutorial

Starting off Simple

Let's assume that you have just finished a basic implementation of your application, and you have created the following files:

• hello.cpp
• hello.h
• main.cpp

You will find these files in the examples/qmake/tutorial directory of the Qt distribution. The only other thing you know about the setup of the application is that it's written in Qt. First, using your favorite plain text editor, create a file called hello.pro in examples/qmake/tutorial. The first thing you need to do is add the lines that tell qmake about the source and header files that are part of your development project.

We'll add the source files to the project file first. To do this you need to use the SOURCES variable. Just start a new line with SOURCES += and put hello.cpp after it. You should have something like this:

    SOURCES += hello.cpp

We repeat this for each source file in the project, until we end up with the following:

    SOURCES += hello.cpp
    SOURCES += main.cpp

If you prefer to use a Make-like syntax, with all the files listed in one go you can use the newline escaping like this:

    SOURCES = hello.cpp \
              main.cpp

Now that the source files are listed in the project file, the header files must be added. These are added in exactly the same way as source files, except that the variable name we use is HEADERS.

Once you have done this, your project file should look something like this:

    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp

The target name is set automatically; it is the same as the project file, but with the suffix appropriate to the platform. For example, if the project file is called hello.pro, the target will be hello.exe on Windows and hello on Unix. If you want to use a different name you can set it in the project file:

    TARGET = helloworld

The final step is to set the CONFIG variable. Since this is a Qt application, we need to put qt on the CONFIG line so that qmake will add the relevant libraries to be linked against and ensure that build lines for moc and uic are included in the generated Makefile.

The finished project file should look like this:

    CONFIG += qt
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp

You can now use qmake to generate a Makefile for your application. On the command line, in your project's directory, type the following:

    qmake -o Makefile hello.pro

Then type make or nmake depending on the compiler you use.

For Visual Studio users, qmake can also generate .dsp or .vcproj files, for example:

    qmake -tp vc -o hello.dsp hello.pro

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp

    win32 {
        SOURCES += hellowin.cpp
    }

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp
    win32 {
        SOURCES += hellowin.cpp
    }
    unix {
        SOURCES += hellounix.cpp
    }

    !exists( main.cpp ) {
        error( "No main.cpp file found" )
    }

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp
    win32 {
        SOURCES += hellowin.cpp
    }
    unix {
        SOURCES += hellounix.cpp
    }
    !exists( main.cpp ) {
        error( "No main.cpp file found" )
    }

    win32 {
        debug {
            CONFIG += console
        }
    }

    CONFIG += qt debug
    HEADERS += hello.h
    SOURCES += hello.cpp
    SOURCES += main.cpp
    win32 {
        SOURCES += hellowin.cpp
    }
    unix {
        SOURCES += hellounix.cpp
    }
    !exists( main.cpp ) {
        error( "No main.cpp file found" )
    }
    win32:debug {
        CONFIG += console
    }