Viadeo Twitter Google Bookmarks ! Facebook Digg del.icio.us MySpace Yahoo MyWeb Blinklist Netvouz Reddit Simpy StumbleUpon Bookmarks Windows Live Favorites 
Logo Documentation Qt ·  Page d'accueil  ·  Toutes les classes  ·  Toutes les fonctions  ·  Vues d'ensemble  · 

Using QML Behaviors with States

Using Behaviors with States

In some cases you may choose to use a Behavior to animate a property change caused by a state change. While this works well for some situations, in other situations it may lead to unexpected behavior.

Here's an example that shows the problem:

 import QtQuick 1.0

 Rectangle {
     width: 400
     height: 400

     Rectangle {
         id: coloredRect
         width: 100
         height: 100
         anchors.centerIn: parent

         color: "red"
         Behavior on color {
             ColorAnimation {}
         }

         MouseArea {
             id: mouser
             anchors.fill: parent
             hoverEnabled: true
         }

         states: State {
             name: "GreenState"
             when: mouser.containsMouse

             PropertyChanges {
                 target: coloredRect
                 color: "green"
             }
         }
     }
 }

Testing the example by quickly and repeatedly moving the mouse in to and out of the colored rectangle shows that the colored rectangle will settle into a green color over time, never returning to full red. This is not what we wanted! The problem occurs because we have used a Behavior to animate the change in color, and our state change is trigged by the mouse entering or exiting the MouseArea, which is easily interrupted.

To state the problem more formally, using States and Behaviors together can cause unexpected behavior when:

  • a Behavior is used to animate a property change, specifically when moving from an explicitly defined state back to the implicit base state; and
  • this Behavior can be interrupted to (re-)enter an explicitly defined state.

The problem occurs because of the way the base state is defined for QML: as the "snapshot" state of the application just prior to entering an explicitly defined state. In this case, if we are in the process of animating from green back to red, and interrupt the animation to return to "GreenState", the base state will include the color in its intermediate, mid-animation form.

While future versions of QML should be able to handle this situation more gracefully, there are currently several ways to rework your application to avoid this problem.

1. Use a transition to animate the change, rather than a Behavior.

 import QtQuick 1.0

 Rectangle {
     width: 400
     height: 400

     Rectangle {
         id: coloredRect
         width: 100
         height: 100
         anchors.centerIn: parent

         color: "red"

         MouseArea {
             id: mouser
             anchors.fill: parent
             hoverEnabled: true
         }

         states: State {
             name: "GreenState"
             when: mouser.containsMouse

             PropertyChanges {
                 target: coloredRect
                 color: "green"
             }
         }

         transitions: Transition {
             ColorAnimation {}
         }
     }
 }

2. Use a conditional binding to change the property value, rather than a state

 import QtQuick 1.0

 Rectangle {
     width: 400
     height: 400

     Rectangle {
         id: coloredRect
         width: 100
         height: 100
         anchors.centerIn: parent

         color: mouser.containsMouse ? "green" : "red"
         Behavior on color {
             ColorAnimation {}
         }

         MouseArea {
             id: mouser
             anchors.fill: parent
             hoverEnabled: true
         }
     }
 }

3. Use only explicitly defined states, rather than an implicit base state

 import QtQuick 1.0

 Rectangle {
     width: 400
     height: 400

     Rectangle {
         id: coloredRect
         width: 100
         height: 100
         anchors.centerIn: parent

         Behavior on color {
             ColorAnimation {}
         }

         MouseArea {
             id: mouser
             anchors.fill: parent
             hoverEnabled: true
         }

         states: [
         State {
             name: "GreenState"
             when: mouser.containsMouse

             PropertyChanges {
                 target: coloredRect
                 color: "green"
             }
         },
         State {
             name: "RedState"
             when: !mouser.containsMouse

             PropertyChanges {
                 target: coloredRect
                 color: "red"
             }
         }]
     }
 }
Publicité

Best Of

Actualités les plus lues

Semaine
Mois
Année
  1. « Quelque chose ne va vraiment pas avec les développeurs "modernes" », un développeur à "l'ancienne" critique la multiplication des bibliothèques 53
  2. Les développeurs ignorent-ils trop les failles découvertes dans leur code ? Prenez-vous en compte les remarques des autres ? 17
  3. Apercevoir la troisième dimension ou l'utilisation multithreadée d'OpenGL dans Qt, un article des Qt Quarterly traduit par Guillaume Belz 0
  4. BlackBerry 10 : premières images du prochain OS de RIM qui devrait intégrer des widgets et des tuiles inspirées de Windows Phone 0
  5. Quelles nouveautés de C++11 Visual C++ doit-il rapidement intégrer ? Donnez-nous votre avis 10
  6. Adieu qmake, bienvenue qbs : Qt Building Suite, un outil déclaratif et extensible pour la compilation de projets Qt 17
  7. La rubrique Qt a besoin de vous ! 1
Page suivante

Le Qt Labs au hasard

Logo

Le coût des commodités

Les Qt Labs sont les laboratoires des développeurs de Qt, où ils peuvent partager des impressions sur le framework, son utilisation, ce que pourrait être son futur. Lire l'article.

Communauté

Ressources

Liens utiles

Contact

  • Vous souhaitez rejoindre la rédaction ou proposer un tutoriel, une traduction, une question... ? Postez dans le forum Contribuez ou contactez-nous par MP ou par email (voir en bas de page).

Qt dans le magazine

Cette page est une traduction d'une page de la documentation de Qt, écrite par Nokia Corporation and/or its subsidiary(-ies). Les éventuels problèmes résultant d'une mauvaise traduction ne sont pas imputables à Nokia. Qt 4.7
Copyright © 2012 Developpez LLC. Tous droits réservés Developpez LLC. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents et images sans l'autorisation expresse de Developpez LLC. Sinon, vous encourez selon la loi jusqu'à 3 ans de prison et jusqu'à 300 000 E de dommages et intérêts. Cette page est déposée à la SACD.
Vous avez déniché une erreur ? Un bug ? Une redirection cassée ? Ou tout autre problème, quel qu'il soit ? Ou bien vous désirez participer à ce projet de traduction ? N'hésitez pas à nous contacter ou par MP !
 
 
 
 
Partenaires

Hébergement Web