SearchResultDelegate.qml Example File

 /****************************************************************************
 **
 ** Copyright (C) 2012 Nokia Corporation and/or its subsidiary(-ies).
 ** Contact: http://www.qt-project.org/
 **
 ** This file is part of the examples of the Qt Toolkit.
 **
 ** $QT_BEGIN_LICENSE:BSD$
 ** You may use this file under the terms of the BSD license as follows:
 **
 ** "Redistribution and use in source and binary forms, with or without
 ** modification, are permitted provided that the following conditions are
 ** met:
 **   * Redistributions of source code must retain the above copyright
 **     notice, this list of conditions and the following disclaimer.
 **   * Redistributions in binary form must reproduce the above copyright
 **     notice, this list of conditions and the following disclaimer in
 **     the documentation and/or other materials provided with the
 **     distribution.
 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
 **     the names of its contributors may be used to endorse or promote
 **     products derived from this software without specific prior written
 **     permission.
 **
 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
 **
 ** $QT_END_LICENSE$
 **
 ****************************************************************************/

 import QtQuick 2.0
 import QtLocation 5.0
 import "PlacesUtils.js" as PlacesUtils

 Item {
     id: root

     signal displayPlaceDetails(variant data)
     signal searchFor(string query)

     width: parent.width
     height: childrenRect.height

     Component {
         id: placeComponent

         Item {
             id: placeRoot

             height: childrenRect.height
             width: parent.width

             Rectangle {
                 anchors.fill: parent
                 color: "#dbffde"
                 visible: model.sponsored !== undefined ? model.sponsored : false
             }

             Column {
                 width: parent.width

                 Row {
                     Image {
                         visible: (place.favorite != null)
                         source: "../../resources/star.png"
                         height: placeName.height
                         fillMode: Image.PreserveAspectFit
                     }

                     Text { id: placeName; text: place.favorite ? place.favorite.name : place.name }
                 }
                 Text { id: distanceText; text: PlacesUtils.prettyDistance(distance); font.italic: true }
                 Text {
                     text: qsTr("Sponsored result")
                     horizontalAlignment: Text.AlignRight
                     font.pixelSize: 8
                     width: parent.width
                     visible: model.sponsored !== undefined ? model.sponsored : false
                 }
             }

             MouseArea {
                 anchors.fill: parent

                 onPressed: placeRoot.state = "Pressed"
                 onReleased: placeRoot.state = ""
                 onCanceled: placeRoot.state = ""

                 onClicked: {
                     if (model.type === undefined || type === PlaceSearchModel.PlaceResult) {
                         if (!place.detailsFetched)
                             place.getDetails();

                         root.displayPlaceDetails({
                                                  distance: model.distance,
                                                  place: model.place,
                     });
                     }
                 }
             }

             states: [
                 State {
                     name: ""
                 },
                 State {
                     name: "Pressed"
                     PropertyChanges { target: placeName; color: "#1C94FC"}
                     PropertyChanges { target: distanceText; color: "#1C94FC"}
                 }
             ]
         }
     }

     Component {
         id: correctionComponent
         Item {
             id: correctionRoot

             Text {
                 id: correctionText
                 width: parent.width
                 text: "Did you mean " + correction + "?"

                 MouseArea {
                     anchors.fill: parent

                     onPressed: correctionRoot.state = "Pressed"
                     onReleased: correctionRoot.state = ""
                     onCanceled: correctionRoot.state = ""

                     onClicked: root.searchFor(correction);
                 }
             }

             states: [
                 State {
                     name: ""
                 },
                 State {
                     name: "Pressed"
                     PropertyChanges { target: correctionText; color: "#1C94FC"}
                 }
             ]
         }
     }

     Loader {
         anchors.left: parent.left
         anchors.right: parent.right

         sourceComponent: (model.type === undefined || model.type === PlaceSearchModel.PlaceResult) ? placeComponent : correctionComponent
     }
 }