AnchorChanges

Detailed Description

The AnchorChanges element is used to modify the anchors of an item in a State.

AnchorChanges cannot be used to modify the margins on an item. For this, use PropertyChanges intead.

In the following example we change the top and bottom anchors of an item using AnchorChanges, and the top and bottom anchor margins using PropertyChanges:

 import QtQuick 2.0

 Rectangle {
     id: window
     width: 120; height: 120
     color: "black"

     Rectangle { id: myRect; width: 50; height: 50; color: "red" }

     states: State {
         name: "reanchored"

         AnchorChanges {
             target: myRect
             anchors.top: window.top
             anchors.bottom: window.bottom
         }
         PropertyChanges {
             target: myRect
             anchors.topMargin: 10
             anchors.bottomMargin: 10
         }
     }

     MouseArea { anchors.fill: parent; onClicked: window.state = "reanchored" }
 }

[Missing image anchorchanges.png]

AnchorChanges can be animated using AnchorAnimation.

 //animate our anchor changes
 Transition {
     AnchorAnimation {}
 }

Changes to anchor margins can be animated using NumberAnimation.

For more information on anchors see Anchor Layouts.

Property Documentation

 AnchorChanges {
     target: myItem
     anchors.left: undefined          //remove myItem's left anchor
     anchors.right: otherItem.right
 }