Viadeo Twitter Google Bookmarks ! Facebook Digg del.icio.us MySpace Yahoo MyWeb Blinklist Netvouz Reddit Simpy StumbleUpon Bookmarks Windows Live Favorites 
Logo Documentation Qt ·  Page d'accueil  ·  Toutes les classes  ·  Classes principales  ·  Annotées  ·  Classes groupées  ·  Modules  ·  Fonctions  · 

TextEdit

The TextEdit item displays multiple lines of editable formatted text. More...

Inherits Item

Properties

Signals

Methods

Detailed Description

The TextEdit item displays a block of editable, formatted text.

It can display both plain and rich text. For example:

 TextEdit {
     width: 240
     text: "<b>Hello</b> <i>World!</i>"
     font.family: "Helvetica"
     font.pointSize: 20
     color: "blue"
     focus: true
 }

Setting focus to true enables the TextEdit item to receive keyboard focus.

Note that the TextEdit does not implement scrolling, following the cursor, or other behaviors specific to a look-and-feel. For example, to add flickable scrolling that follows the cursor:

 Flickable {
     id: flick

     width: 300; height: 200;
     contentWidth: edit.paintedWidth
     contentHeight: edit.paintedHeight
     clip: true

     function ensureVisible(r)
     {
         if (contentX >= r.x)
             contentX = r.x;
         else if (contentX+width <= r.x+r.width)
             contentX = r.x+r.width-width;
         if (contentY >= r.y)
             contentY = r.y;
         else if (contentY+height <= r.y+r.height)
             contentY = r.y+r.height-height;
     }

     TextEdit {
         id: edit
         width: flick.width
         height: flick.height
         focus: true
         wrapMode: TextEdit.Wrap
         onCursorRectangleChanged: flick.ensureVisible(cursorRectangle)
     }
 }

A particular look-and-feel might use smooth scrolling (eg. using SmoothedFollow), might have a visible scrollbar, or a scrollbar that fades in to show location, etc.

Clipboard support is provided by the cut(), copy(), and paste() functions, and the selection can be handled in a traditional "mouse" mechanism by setting selectByMouse, or handled completely from QML by manipulating selectionStart and selectionEnd, or using selectAll() or selectWord().

You can translate between cursor positions (characters from the start of the document) and pixel points using positionAt() and positionToRectangle().

See also Text, TextInput, and Text Selection example.

Property Documentation

activeFocusOnPress : bool

Whether the TextEdit should gain active focus on a mouse press. By default this is set to true.


baseUrl : url

This property specifies a base URL which is used to resolve relative URLs within the text.

By default is the url of the TextEdit element.


read-onlycanPaste : bool

Returns true if the TextEdit is writable and the content of the clipboard is suitable for pasting into the TextEdit.


read-onlycanRedo : bool

Returns true if the TextEdit is writable and there are undone operations that can be redone.


read-onlycanUndo : bool

Returns true if the TextEdit is writable and there are previous operations that can be undone.


color : color

The text color.

 // green text using hexadecimal notation
 TextEdit { color: "#00FF00" }
 // steelblue text using SVG color name
 TextEdit { color: "steelblue" }

read-onlycontentHeight : real

Returns the height of the text, including the height past the height that is covered if the text does not fit within the set height.


read-onlycontentWidth : real

Returns the width of the text, including the width past the width which is covered due to insufficient wrapping if wrapMode is set.


cursorDelegate : Component

The delegate for the cursor in the TextEdit.

If you set a cursorDelegate for a TextEdit, this delegate will be used for drawing the cursor instead of the standard cursor. An instance of the delegate will be created and managed by the text edit when a cursor is needed, and the x and y properties of delegate instance will be set so as to be one pixel before the top left of the current character.

Note that the root item of the delegate component must be a QQuickItem or QQuickItem derived item.


cursorPosition : int

The position of the cursor in the TextEdit.


read-onlycursorRectangle : rectangle

The rectangle where the standard text cursor is rendered within the text edit. Read-only.

The position and height of a custom cursorDelegate are updated to follow the cursorRectangle automatically when it changes. The width of the delegate is unaffected by changes in the cursor rectangle.


cursorVisible : bool

If true the text edit shows a cursor.

This property is set and unset when the text edit gets active focus, but it can also be set directly (useful, for example, if a KeyProxy might forward keys to it).


font.bold : bool

Sets whether the font weight is bold.


font.capitalization : enumeration

Sets the capitalization for the text.

  • Font.MixedCase - This is the normal text rendering option where no capitalization change is applied.
  • Font.AllUppercase - This alters the text to be rendered in all uppercase type.
  • Font.AllLowercase - This alters the text to be rendered in all lowercase type.
  • Font.SmallCaps - This alters the text to be rendered in small-caps type.
  • Font.Capitalize - This alters the text to be rendered with the first character of each word as an uppercase character.
 TextEdit { text: "Hello"; font.capitalization: Font.AllLowercase }

font.family : string

Sets the family name of the font.

The family name is case insensitive and may optionally include a foundry name, e.g. "Helvetica [Cronyx]". If the family is available from more than one foundry and the foundry isn't specified, an arbitrary foundry is chosen. If the family isn't available a family will be set using the font matching algorithm.


font.italic : bool

Sets whether the font has an italic style.


font.letterSpacing : real

Sets the letter spacing for the font.

Letter spacing changes the default spacing between individual letters in the font. A positive value increases the letter spacing by the corresponding pixels; a negative value decreases the spacing.


font.pixelSize : int

Sets the font size in pixels.

Using this function makes the font device dependent. Use TextEdit::font.pointSize to set the size of the font in a device independent manner.


font.pointSize : real

Sets the font size in points. The point size must be greater than zero.


font.strikeout : bool

Sets whether the font has a strikeout style.


font.underline : bool

Sets whether the text is underlined.


font.weight : enumeration

Sets the font's weight.

The weight can be one of:

  • Font.Light
  • Font.Normal - the default
  • Font.DemiBold
  • Font.Bold
  • Font.Black
 TextEdit { text: "Hello"; font.weight: Font.DemiBold }

font.wordSpacing : real

Sets the word spacing for the font.

Word spacing changes the default spacing between individual words. A positive value increases the word spacing by a corresponding amount of pixels, while a negative value decreases the inter-word spacing accordingly.


horizontalAlignment : enumeration

verticalAlignment : enumeration

effectiveHorizontalAlignment : enumeration

Sets the horizontal and vertical alignment of the text within the TextEdit item's width and height. By default, the text alignment follows the natural alignment of the text, for example text that is read from left to right will be aligned to the left.

Valid values for horizontalAlignment are:

Valid values for verticalAlignment are:

When using the attached property LayoutMirroring::enabled to mirror application layouts, the horizontal alignment of text will also be mirrored. However, the property horizontalAlignment will remain unchanged. To query the effective horizontal alignment of TextEdit, use the read-only property effectiveHorizontalAlignment.


read-onlyinputMethodComposing : bool

This property holds whether the TextEdit has partial text input from an input method.

While it is composing an input method may rely on mouse or key events from the TextEdit to edit or commit the partial text. This property can be used to determine when to disable events handlers that may interfere with the correct operation of an input method.


inputMethodHints : enumeration

Provides hints to the input method about the expected content of the text edit and how it should operate.

The value is a bit-wise combination of flags or Qt.ImhNone if no hints are set.

Flags that alter behaviour are:

  • Qt.ImhHiddenText - Characters should be hidden, as is typically used when entering passwords.
  • Qt.ImhSensitiveData - Typed text should not be stored by the active input method in any persistent storage like predictive user dictionary.
  • Qt.ImhNoAutoUppercase - The input method should not try to automatically switch to upper case when a sentence ends.
  • Qt.ImhPreferNumbers - Numbers are preferred (but not required).
  • Qt.ImhPreferUppercase - Upper case letters are preferred (but not required).
  • Qt.ImhPreferLowercase - Lower case letters are preferred (but not required).
  • Qt.ImhNoPredictiveText - Do not use predictive text (i.e. dictionary lookup) while typing.
  • Qt.ImhDate - The text editor functions as a date field.
  • Qt.ImhTime - The text editor functions as a time field.

Flags that restrict input (exclusive flags) are:

  • Qt.ImhDigitsOnly - Only digits are allowed.
  • Qt.ImhFormattedNumbersOnly - Only number input is allowed. This includes decimal point and minus sign.
  • Qt.ImhUppercaseOnly - Only upper case letter input is allowed.
  • Qt.ImhLowercaseOnly - Only lower case letter input is allowed.
  • Qt.ImhDialableCharactersOnly - Only characters suitable for phone dialing are allowed.
  • Qt.ImhEmailCharactersOnly - Only characters suitable for email addresses are allowed.
  • Qt.ImhUrlCharactersOnly - Only characters suitable for URLs are allowed.

Masks:

  • Qt.ImhExclusiveInputMask - This mask yields nonzero if any of the exclusive flags are used.

read-onlylength : int

Returns the total number of plain text characters in the TextEdit item.

As this number doesn't include any formatting markup it may not be the same as the length of the string returned by the text property.

This property can be faster than querying the length the text property as it doesn't require any copying or conversion of the TextEdit's internal string data.


read-onlylineCount : int

Returns the total number of lines in the textEdit item.


mouseSelectionMode : enum

Specifies how text should be selected using a mouse.

  • TextEdit.SelectCharacters - The selection is updated with individual characters. (Default)
  • TextEdit.SelectWords - The selection is updated with whole words.

This property only applies when selectByMouse is true.


persistentSelection : bool

Whether the TextEdit should keep the selection visible when it loses active focus to another item in the scene. By default this is set to true;


readOnly : bool

Whether the user can interact with the TextEdit item. If this property is set to true the text cannot be edited by user interaction.

By default this property is false.


selectByMouse : bool

Defaults to false.

If true, the user can use the mouse to select text in some platform-specific way. Note that for some platforms this may not be an appropriate interaction (eg. may conflict with how the text needs to behave inside a Flickable.


read-onlyselectedText : string

This read-only property provides the text currently selected in the text edit.

It is equivalent to the following snippet, but is faster and easier to use.

 //myTextEdit is the id of the TextEdit
 myTextEdit.text.toString().substring(myTextEdit.selectionStart,
         myTextEdit.selectionEnd);

selectedTextColor : color

The selected text color, used in selections.


selectionColor : color

The text highlight color, used behind selections.


read-onlyselectionEnd : int

The cursor position after the last character in the current selection.

This property is read-only. To change the selection, use select(start,end), selectAll(), or selectWord().

See also selectionStart, cursorPosition, and selectedText.


read-onlyselectionStart : int

The cursor position before the first character in the current selection.

This property is read-only. To change the selection, use select(start,end), selectAll(), or selectWord().

See also selectionEnd, cursorPosition, and selectedText.


smooth : bool

This property holds whether the text is smoothly scaled or transformed.

Smooth filtering gives better visual quality, but is slower. If the item is displayed at its natural size, this property has no visual or performance effect.

Note: Generally scaling artifacts are only visible if the item is stationary on the screen. A common pattern when animating an item is to disable smooth filtering at the beginning of the animation and reenable it at the conclusion.


text : string

The text to display. If the text format is AutoText the text edit will automatically determine whether the text should be treated as rich text. This determination is made using Qt::mightBeRichText().


textFormat : enumeration

The way the text property should be displayed.

The default is TextEdit.PlainText. If the text format is TextEdit.AutoText the text edit will automatically determine whether the text should be treated as rich text. This determination is made using Qt::mightBeRichText().

 Column {
     TextEdit {
         font.pointSize: 24
         text: "<b>Hello</b> <i>World!</i>"
     }
     TextEdit {
         font.pointSize: 24
         textFormat: TextEdit.RichText
         text: "<b>Hello</b> <i>World!</i>"
     }
     TextEdit {
         font.pointSize: 24
         textFormat: TextEdit.PlainText
         text: "<b>Hello</b> <i>World!</i>"
     }
 }

[Missing image declarative-textformat.png]


textMargin : real

The margin, in pixels, around the text in the TextEdit.


wrapMode : enumeration

Set this property to wrap the text to the TextEdit item's width. The text will only wrap if an explicit width has been set.

  • TextEdit.NoWrap - no wrapping will be performed. If the text contains insufficient newlines, then implicitWidth will exceed a set width.
  • TextEdit.WordWrap - wrapping is done on word boundaries only. If a word is too long, implicitWidth will exceed a set width.
  • TextEdit.WrapAnywhere - wrapping is done at any point on a line, even if it occurs in the middle of a word.
  • TextEdit.Wrap - if possible, wrapping occurs at a word boundary; otherwise it will occur at the appropriate point on the line, even in the middle of a word.

The default is TextEdit.NoWrap. If you set a width, consider using TextEdit.Wrap.


Signal Documentation

TextEdit::onLinkActivated(string link)

This handler is called when the user clicks on a link embedded in the text. The link must be in rich text or HTML format and the link string provides access to the particular link.


Method Documentation

TextEdit::copy()

Copies the currently selected text to the system clipboard.


TextEdit::cut()

Moves the currently selected text to the system clipboard.


int TextEdit::positionAt(int x, int y)

Returns the text position closest to pixel position (x, y).

Position 0 is before the first character, position 1 is after the first character but before the second, and so on until position text.length, which is after all characters.


TextEdit::paste()

Replaces the currently selected text by the contents of the system clipboard.


rectangle TextEdit::positionToRectangle(position)

Returns the rectangle at the given position in the text. The x, y, and height properties correspond to the cursor that would describe that position.


string TextEdit::getFormattedText(int start, int end)

Returns the section of text that is between the start and end positions.

The returned text will be formatted according the textFormat property.


string TextEdit::getText(int start, int end)

Returns the section of text that is between the start and end positions.

The returned text does not include any rich text formatting.


void TextEdit::closeSoftwareInputPanel()

Closes a software input panel like a virtual keyboard shown on the screen, useful for customizing when you want the input keyboard to be shown and hidden in your application.

By default the opening of input panels follows the platform style. Input panels are always closed if no editor has active focus.

You can disable the automatic behavior by setting the property activeFocusOnPress to false and use functions openSoftwareInputPanel() and closeSoftwareInputPanel() to implement the behavior you want.

Only relevant on platforms, which provide virtual keyboards.

 import QtQuick 2.0
 TextEdit {
     id: textEdit
     text: "Hello world!"
     activeFocusOnPress: false
     MouseArea {
         anchors.fill: parent
         onClicked: {
             if (!textEdit.activeFocus) {
                 textEdit.forceActiveFocus();
                 textEdit.openSoftwareInputPanel();
             } else {
                 textEdit.focus = false;
             }
         }
         onPressAndHold: textEdit.closeSoftwareInputPanel();
     }
 }

void TextEdit::deselect()

Removes active text selection.


void TextEdit::insert(int position, string text)

Inserts text into the TextEdit at position.


void TextEdit::isRightToLeft(int start, int end)

Returns true if the natural reading direction of the editor text found between positions start and end is right to left.


void TextEdit::moveCursorSelection(int position, SelectionMode mode = TextEdit.SelectCharacters)

Moves the cursor to position and updates the selection according to the optional mode parameter. (To only move the cursor, set the cursorPosition property.)

When this method is called it additionally sets either the selectionStart or the selectionEnd (whichever was at the previous cursor position) to the specified position. This allows you to easily extend and contract the selected text range.

The selection mode specifies whether the selection is updated on a per character or a per word basis. If not specified the selection mode will default to TextEdit.SelectCharacters.

  • TextEdit.SelectCharacters - Sets either the selectionStart or selectionEnd (whichever was at the previous cursor position) to the specified position.
  • TextEdit.SelectWords - Sets the selectionStart and selectionEnd to include all words between the specified position and the previous cursor position. Words partially in the range are included.

For example, take this sequence of calls:

 cursorPosition = 5
 moveCursorSelection(9, TextEdit.SelectCharacters)
 moveCursorSelection(7, TextEdit.SelectCharacters)

This moves the cursor to position 5, extend the selection end from 5 to 9 and then retract the selection end from 9 to 7, leaving the text from position 5 to 7 selected (the 6th and 7th characters).

The same sequence with TextEdit.SelectWords will extend the selection start to a word boundary before or on position 5 and extend the selection end to a word boundary on or past position 9.


void TextEdit::openSoftwareInputPanel()

Opens software input panels like virtual keyboards for typing, useful for customizing when you want the input keyboard to be shown and hidden in your application.

By default the opening of input panels follows the platform style. Input panels are always closed if no editor has active focus.

You can disable the automatic behavior by setting the property activeFocusOnPress to false and use functions openSoftwareInputPanel() and closeSoftwareInputPanel() to implement the behavior you want.

Only relevant on platforms, which provide virtual keyboards.

 import QtQuick 2.0
 TextEdit {
     id: textEdit
     text: "Hello world!"
     activeFocusOnPress: false
     MouseArea {
         anchors.fill: parent
         onClicked: {
             if (!textEdit.activeFocus) {
                 textEdit.forceActiveFocus();
                 textEdit.openSoftwareInputPanel();
             } else {
                 textEdit.focus = false;
             }
         }
         onPressAndHold: textEdit.closeSoftwareInputPanel();
     }
 }

void TextEdit::select(int start, int end)

Causes the text from start to end to be selected.

If either start or end is out of range, the selection is not changed.

After calling this, selectionStart will become the lesser and selectionEnd will become the greater (regardless of the order passed to this method).

See also selectionStart and selectionEnd.


void TextEdit::selectAll()

Causes all text to be selected.


void TextEdit::selectWord()

Causes the word closest to the current cursor position to be selected.


Cette page est une traduction d'une page de la documentation de Qt, écrite par Nokia Corporation and/or its subsidiary(-ies). Les éventuels problèmes résultant d'une mauvaise traduction ne sont pas imputables à Nokia. Qt 5.0-snapshot
Copyright © 2012 Developpez LLC. Tous droits réservés Developpez LLC. Aucune reproduction, même partielle, ne peut être faite de ce site et de l'ensemble de son contenu : textes, documents et images sans l'autorisation expresse de Developpez LLC. Sinon, vous encourez selon la loi jusqu'à 3 ans de prison et jusqu'à 300 000 E de dommages et intérêts. Cette page est déposée à la SACD.
Vous avez déniché une erreur ? Un bug ? Une redirection cassée ? Ou tout autre problème, quel qu'il soit ? Ou bien vous désirez participer à ce projet de traduction ? N'hésitez pas à nous contacter ou par MP !
 
 
 
 
Partenaires

Hébergement Web